#include <Wire.h>
#include <LiquidCrystal_PCF8574.h>

LiquidCrystal_PCF8574 lcd(0x27);

const int sensorHumedad = A0;
const int releBomba = 7;
const int botonManual = 2;

int limiteSeco = 550;

unsigned long intervaloEntreRiegos = 30000; // Exposición: 30 segundos
unsigned long intervaloLectura = 2000;
unsigned long duracionRiego = 3000;

unsigned long tiempoAnteriorLectura = 0;
unsigned long tiempoUltimoRiego = 0;

bool primerRiegoAutomatico = true;

void setup() {
  Serial.begin(9600);
  Wire.begin();

  pinMode(releBomba, OUTPUT);
  pinMode(botonManual, INPUT_PULLUP);

  digitalWrite(releBomba, HIGH);

  lcd.begin(16, 2);
  lcd.setBacklight(255);
  lcd.display();
  lcd.clear();

  lcd.setCursor(0, 0);
  lcd.print("SISTEMA RIEGO");
  lcd.setCursor(0, 1);
  lcd.print("INICIANDO...");
  delay(2000);
  lcd.clear();
}

void loop() {
  unsigned long tiempoActual = millis();

  if (digitalRead(botonManual) == LOW) {
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("RIEGO MANUAL");
    lcd.setCursor(0, 1);
    lcd.print("BOMBA ACTIVA");

    regar();

    tiempoUltimoRiego = tiempoActual;
    primerRiegoAutomatico = false;
    delay(1000);
  }

  if (tiempoActual - tiempoAnteriorLectura >= intervaloLectura) {
    tiempoAnteriorLectura = tiempoActual;

    int humedad = analogRead(sensorHumedad);

    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("HUMEDAD:");
    lcd.print(humedad);

    if (humedad > limiteSeco) {
      lcd.setCursor(0, 1);
      lcd.print("ESTADO: SECO");

      if (primerRiegoAutomatico || tiempoActual - tiempoUltimoRiego >= intervaloEntreRiegos) {
        lcd.clear();
        lcd.setCursor(0, 0);
        lcd.print("TIERRA SECA");
        lcd.setCursor(0, 1);
        lcd.print("REGANDO...");

        regar();

        tiempoUltimoRiego = tiempoActual;
        primerRiegoAutomatico = false;
      }
    } else {
      lcd.setCursor(0, 1);
      lcd.print("ESTADO: HUMEDA");
    }
  }
}

void regar() {
  digitalWrite(releBomba, LOW);
  delay(duracionRiego);
  digitalWrite(releBomba, HIGH);

  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print("RIEGO");
  lcd.setCursor(0, 1);
  lcd.print("FINALIZADO");
  delay(1200);
}